K&P SFD-800

Schaltplan

Der Schaltplan stammt urspruenglich aus dem K&P SFD800 Handbuch, das aufgrund des schlechten Bildscans einiges an Entzifferungsarbeit erforderte. Dieser Schaltplan wurde anschliessend in KiCAD erfasst und ist unten dargestellt.

Automatisiertes Setup und Build (empfohlen)

macOS / Linux — setup_SFD800.sh

chmod +x setup_SFD800.sh
./setup_SFD800.sh

Windows 10 / 11 — Doppelklick auf setup_SFD800_windows.cmd oder fuehren Sie den nativen Installer an einer PowerShell-Eingabeaufforderung aus:

Set-ExecutionPolicy -Scope Process -ExecutionPolicy Bypass
.\setup_SFD800_windows_native.ps1

./build_cupl.sh      # -> CUPL/SFD800.jed

GAL

Das urspruengliche Bauteil von K&P war ein PAL, ein einmal programmierbares Logikbauelement mit gesetzter Schutzsicherung. Da der PAL ein einfaches Bauelement ist – 12 Eingaenge, 8 Ausgaenge – waere es einfach gewesen, die Logik durch Messen zu ermitteln. Da der Entwurf tatsaechlich recht einfach ist und ich umfangreiche Erfahrung mit Diskettenlaufwerken hatte, als ich die RFS- und TZFS-Monitore schrieb, entschied ich mich, die Logik von Grund auf neu zu schreiben, basierend auf meinem Wissen.

Ich verwendete WinCUPL zum Kompilieren des Codes und testete den GAL auf der originalen K&P SFD800-Karte zur Verifikation. Der Code ist unten dargestellt, und wie zu sehen ist, handelt es sich lediglich um Adressdekodierung und die Erzeugung von Auswahlsignalen.

Name     SFD800 ;
PartNo   PAL12L6 ;
Date     20/05/2021 ;
Revision 01 ;
Designer Philip Smart ;
Company  engineers@work ;
Assembly SFD800 ;
Location  ;
Device   g16v8a;

/* *************** INPUT PINS *********************/
PIN  1   = A0                        ; /* Address bus A0                  */ 
PIN  2   = A1                        ; /*             A1                  */ 
PIN  3   = A2                        ; /*             A2                  */ 
PIN  4   = A3                        ; /*             A3                  */ 
PIN  6   = A4                        ; /*             A4                  */ 
PIN  7   = A5                        ; /*             A5                  */ 
PIN  8   = A6                        ; /*             A6                  */ 
PIN  9   = A7                        ; /*             A7                  */ 
PIN 19   = IORQn                     ; /* Z80 IORQ active low             */ 
PIN 11   = WRn                       ; /* Z80 WR active low               */ 
PIN 12   = RDn                       ; /* Z80 RD active low               */ 
PIN 5    = RESET                     ; /* System Reset active high        */ 

/* *************** OUTPUT PINS *********************/
PIN 13   = BUSn                      ; /* BUS direction, low = read into Z80, high = write to FD IC's */ 
PIN 18   = FDCn                      ; /* WD1773 Chip Select active low I/O - Address 0xD8 .. 0xDB */ 
PIN 14   = DRIVEn                    ; /* Disk Drive Select active low - Address 0xDC */ 
PIN 17   = DDENn                     ; /* Drive Density select active low - Address 0xDE */ 
PIN 15   = RESn                      ; /* Peripheral Reset active low */ 
PIN 16   = SIDEn                     ; /* Disk Head Select active low - Address 0xDD */ 

/* Decoder equations. */
FIELD ADDR = [A7..A0];
WD1773SEL  = !IORQn & ADDR:[D8..DB];
SIDESEL    = !IORQn & !WRn & ADDR:[DD..DD];
DRIVESEL   = !IORQn & !WRn & ADDR:[DC..DC];
DDENSEL    = !IORQn & !WRn & ADDR:[DE..DE];  
BUSREAD    = !IORQn & !RDn & ADDR:[D8..DE];

/* Assign output pins based on equations. */
BUSn       = !BUSREAD;
RESn       = !RESET;
FDCn       = !WD1773SEL;
SIDEn      = !SIDESEL;
DRIVEn     = !DRIVESEL;
DDENn      = !DDENSEL;

Leiterplatte/PCB

Die Leiterplatte unterscheidet sich vom Original dadurch, dass ich KiCAD anstelle von handgezeichneten Bildern verwendete. Der Vorteil von KiCAD liegt in moderneren Routing-Techniken und Kupferfuellungen.

Dokumentation

K&P SFD800 Handbuch

Der obige Link laedt das originale K&P Benutzerhandbuch herunter, das auf Deutsch verfasst ist. Die beste Uebersetzungsmethode ist die Verwendung der Google Translate-App auf Ihrem Smartphone mit der Echtzeit-Kamerauebersetzungsfunktion, eingestellt auf Deutsch-><Ihre Sprache>.

Preis

Die folgende Tabelle zeigt die Kosten fuer die Herstellung einer Leiterplatte. Die Preise sind nicht ganz exakt, da man haeufig in Stueckzahlen von 10/50/100 kaufen und die Kosten ueber die Anzahl der gefertigten Platinen umlegen muss. Scrollen Sie nach rechts, um alle Tabellendetails zu sehen.

Dateien

Alle Projektdateien finden Sie auf Gitea.

Danksagungen

Lizenzen

Die GNU General Public License v3